Flash RPG – Creating our Hero 2/2

package com.refrag.necotest03
{
 	//Import our packages
	import flash.display.MovieClip;
	import flash.display.Stage;
	import com.senocular.utils.KeyObject;
	import flash.ui.Keyboard;
	import flash.events.Event;
 
	public class Hero extends MovieClip	{
 
		//Setup our class-wide variables
		private var stageRef:Stage;
		private var key:KeyObject;
		private var facing = "down";
		private var oldfacing;
		private var xv = 0;
		private var yv = 0;
		private var animating = false;
		private var canMoveRight=true;
		private var canMoveLeft=true;
		private var canMoveUp=true;
		private var canMoveDown=true;
 
		public function Hero(stageRef:Stage)
		{
			this.stageRef = stageRef;
			key = new KeyObject(stageRef);
 
			addEventListener(Event.ENTER_FRAME, loop, false, 0, true);
		}
 
		public function loop(e:Event) : void
		{
			//If I'm not hitting anything, let me move everywhere!
			if (!hitTest())
			{
				canMoveRight=true;
				canMoveLeft=true;
				canMoveUp=true;
				canMoveDown=true;
			}
 
			//Keyboard catches
			if (key.isDown(Keyboard.UP)){
				if (canMoveUp)
					y -= 2;
				facing = "up";
				yv=1;
			}
			else if (key.isDown(Keyboard.DOWN)){
				if (canMoveDown)
					y += 2;
				facing = "down";
				yv=1;
			}
			else
				yv=0;
 
			if (key.isDown(Keyboard.LEFT)){
				if (canMoveLeft)
					x -= 2;
				facing = "left";
				xv=1;
			}
			else if (key.isDown(Keyboard.RIGHT)){
				if (canMoveRight)
					x += 2;
				facing = "right";
				xv=1;
			}
			else
				xv=0;
 
			//If I'm not currently animating, or if I've changed directions, lets walk!
			if (oldfacing!=facing || animating==false){
				walk(facing);
				animating=true;
			}
 
			//If my movement velocity hits 0, I'm going to stop.
			if (yv==0 && xv==0){
				stand(facing);
				animating=false;
			}
 
			oldfacing=facing;
 
		}
 
		//My Walk function. Moves the timeline to the right keyframe which contains each animation
		public function walk(d)
		{
			if (d=="left")
				gotoAndStop("WalkLeft");
			else if (d=="right")
				gotoAndStop("WalkRight");
			else if (d=="up")
				gotoAndStop("WalkUp");
			else if (d=="down")
				gotoAndStop("WalkDown");
			else
				trace("Invalid argument passed to Hero.walk()");
		}
 
		//My Stand function. Same as walk, but for my standing frames.
		public function stand(d)
		{
			if (d=="left")
				gotoAndStop("StandLeft");
			else if (d=="right")
				gotoAndStop("StandRight");
			else if (d=="up")
				gotoAndStop("StandUp");
			else if (d=="down")
				gotoAndStop("StandDown");
			else
				trace("Invalid argument passed to Hero.stand()");
		}			
 
		//My hittest function
		private function hitTest() : Boolean
		{
			//Let's pretend that I'm not hitting anything. Let the function prove me wrong.
			var leftTest = 0;
			var rightTest = 0;
			var upTest = 0;
			var downTest = 0;
			var hit = false;
 
			//Like in the court of law, I can move unless proven guilty of collision.
			canMoveRight=true;
			canMoveLeft=true;
			canMoveUp=true;
			canMoveDown=true;
 
			//Loop through all of the objects in the engine enemy list
			for (var i:int = 0; i < Engine.enemyList.length; i++)
			{
				//If a hit is detected, test my specific hit boxes so I know where I can and cant go
				if (hitTestObject(Engine.enemyList[i].hit))
				{
					hit=true;
					if (hitRight.hitTestObject(Engine.enemyList[i].hit))
						rightTest++;
 
					if (hitLeft.hitTestObject(Engine.enemyList[i].hit))
						leftTest++;
 
					if (hitUp.hitTestObject(Engine.enemyList[i].hit))
						upTest++;
 
					if (hitDown.hitTestObject(Engine.enemyList[i].hit))
						downTest++;
				}
 
			}
 
			//Based on the individual hit tests, set my movability options
			if (rightTest>0){
				canMoveRight=false;
				x-=2;
			}
			if (leftTest>0){
				canMoveLeft=false;
				x+=2;
			}
			if (upTest>0){
				canMoveUp=false;
				y+=2;
			}
			if (downTest>0){
				canMoveDown=false;
				y-=2;
			}
			if (hit==true)
				return true;
				else
				return false;
		}
 
	}
 
}

package com.refrag.necotest03
{
	import flash.display.MovieClip;
	import flash.display.Stage;
	import flash.events.Event;
	import flash.display.DisplayObject;
 
	public class Engine extends MovieClip
	{
		public static var enemyList:Array = new Array();
		public static var sortedItems:Array = new Array();
 
		public function Engine()
		{
			//Create our Hero!
			var ourHero:Hero = new Hero(stage);
 
			sortedItems.push(ourHero);
 
			//add it to the display list
			stage.addChild(ourHero);
			ourHero.x = 250;
			ourHero.y = stage.stageHeight /2;
 
			//create our "enemies"
			for (var i:int = 0; i < 4; i++)
			{
				var enemy:Enemy = new Enemy(stage, ourHero);
 
				//add our enemy to the enemyList
				enemyList.push(enemy);
				sortedItems.push(enemy);
 
				stage.addChild(enemy);
			}
 			addEventListener(Event.ENTER_FRAME, loop, false, 0, true);
		}
 
		public function loop(e:Event) : void
		{	
			//We only do 1 thing every frame. Ensure our depth indexing is right.
			arrange();
		}
 
		//Our depth indexing function
		private function arrange():void {
			sortedItems.sortOn("y", Array.NUMERIC);
			var i:int = sortedItems.length;
			while(i--){
				if (stage.getChildIndex(sortedItems[i]) != i) {
					stage.setChildIndex(sortedItems[i], i);
				}
			}
		} 
	}
 
}